home *** CD-ROM | disk | FTP | other *** search
/ Loadstar 97 / 097.d81 / star mistresses (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1992-01-01  |  29.7 KB  |  759 lines
  1. 10 rem ********************************
  2. 20 rem **    star-mistresses v2.1    **
  3. 30 rem **             by             **
  4. 40 rem **        anthony rose        **
  5. 50 rem ********************************
  6. 60 dv=peek(186):ifdv<8thendv=8
  7. 70 gosub3000:goto3040
  8. 80 rem --- random choices ---
  9. 90 fori=1to16:ch$(i)="":next
  10. 100 an=(rnd(1)*16+1):ch$(an)=an$(qt)
  11. 110 fori=1to16:ifch$(i)<>""then160
  12. 120 rn=rnd(1)*n%+1:ifan$(rn)=an$(qt)then120
  13. 130 fl=0:forj=1toi:ifch$(j)=an$(rn)thenfl=1:j=i
  14. 140 next:ifflthen120
  15. 150 ch$(i)=an$(rn)
  16. 160 next:return
  17. 170 rem --- game screen ---
  18. 180 print"[147]";:a$="%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%"
  19. 190 fori=.to23:printa$:next:printa$""
  20. 200 print"[158] * * * * * star mistresses * * * * * "
  21. 210 fori=.to1:print"[150]                                     ":next
  22. 220 fori=1to8:print:printb0$b0$:next
  23. 230 print"[153] question# [159] point value [154]   score   "
  24. 240 print"[153]    000    [159]    00000    [154]   00000   "
  25. 250 return
  26. 260 rem --- print question number ---
  27. 270 poke214,22:print
  28. 280 a$=str$(qn):a$=right$(a$,len(a$)-1)
  29. 290 printtab(8-len(a$))"[153]"a$
  30. 300 return
  31. 310 rem --- print point value ---
  32. 320 poke214,22:print:a$=str$(pv)
  33. 330 a$="000"+right$(a$,len(a$)-1)
  34. 340 printtab(17)"[159]"right$(a$,5)
  35. 350 return
  36. 360 rem --- print question ---
  37. 370 pokes+5,0:pokes+6,240:pokes+1,34:pokes,75:pokes+12,0
  38. 380 pokes+13,240:pokes+8,14:pokes+7,24
  39. 390 poke214,2:print:print"[150]";
  40. 400 a$=qt$(qt):fori=1tolen(a$)
  41. 410 ifmid$(a$,i,1)="+"thenprint:print"";:goto440
  42. 420 pokes+4,17:pokes+11,17:pokes+4,16:pokes+11,16
  43. 430 printmid$(a$,i,1);
  44. 440 next
  45. 450 print"?":return
  46. 460 rem --- print choices ---
  47. 470 poke214,5:print:fori=1to8
  48. 480 printmid$(c$,i,1)""ch$(i)tab(21)ch$(i+8)
  49. 490 print:next:return
  50. 500 rem --- print score ---
  51. 510 poke214,22:print
  52. 520 a$=str$(sc):a$=right$(a$,len(a$)-1)
  53. 530 printtab(35-len(a$))"[154]"a$
  54. 540 return
  55. 550 rem --- bonus prompt ---
  56. 560 poke214,9:print"[129]"
  57. 570 printtab(12)"                "
  58. 580 printtab(12)"  bonus if you  "
  59. 590 printtab(12)" can answer the "
  60. 600 printtab(12)" next question! "
  61. 610 printtab(12)"                "
  62. 620 fori=10to8step-1:r%=i:gosub980:next
  63. 630 fori=8to10:r%=i:gosub980:next
  64. 640 forde=1to3000:next
  65. 650 poke214,9:print
  66. 660 fori=.to2:printtab(12)"       %        ":printtab(12)"%%%%%%%%%%%%%%%%%"
  67. 670 next:return
  68. 680 rem --- clear screen lines ---
  69. 690 poke214,2:print
  70. 700 fori=.to1:print"[150]                                     ":next
  71. 710 fori=1to8:print:printb0$b0$:next
  72. 720 return
  73. 730 rem -- highlight correct answer --
  74. 740 c%=1:r%=an:ifr%>8thenr%=r%-8:c%=2
  75. 750 fori=1to2:gosub900:gosub980
  76. 760 forde=1to100:next:gosub880
  77. 770 forde=1to100:next:next
  78. 780 gosub900:gosub980:return
  79. 790 rem --- clear screens ---
  80. 800 fori=0to12:poke781,i:sys59903:poke781,24-i:sys59903:next:return
  81. 810 rem --- clear title screen ---
  82. 820 poke214,10:print
  83. 830 fori=.to4:printtab(9)b0$:next
  84. 840 forde=1to1200:next:return
  85. 850 rem --- bottom to top ---
  86. 860 fori=24to.step-1:poke781,i:sys59903:next:return
  87. 870 rem --- highlight bar off ---
  88. 880 printtab(t)"[145]"b0$:printtab(t)"[145]"ch$(a):return
  89. 890 rem --- highlight bar on ---
  90. 900 poke214,r%*2+3:print
  91. 910 t=(c%-1)*19:a=(c%-1)*8+r%
  92. 920 printtab(t)mid$(c$,r%,1)b1$
  93. 930 printtab(t)"[145]"ch$(a)
  94. 940 return
  95. 950 rem --- clear sid chip ---
  96. 960 fori=.to24:pokes+i,.:next:pokes+24,15:return
  97. 970 rem --- beep ---
  98. 980 pokes+6,200:pokes+1,r%*5+10
  99. 990 pokes+4,17:forde=1to50:next
  100. 1000 pokes+4,16:return
  101. 1010 rem --- rasberry ---
  102. 1020 pokes+5,0:pokes+6,240
  103. 1030 fori=1024to768step-8
  104. 1040 pokes+1,i/256:pokes,iand255
  105. 1050 pokes+4,33:next:pokes+4,32
  106. 1060 return
  107. 1070 rem --- correct sound ---
  108. 1080 pokes+6,225:pokes+4,17
  109. 1090 fori=1to7:forde=1to180step20
  110. 1100 pokes+1,de:next:next
  111. 1110 pokes+4,0:return
  112. 1120 rem --- meet the champ ---
  113. 1130 pokes+5,41:pokes+6,48
  114. 1140 fori=0to16:pokes+4,17
  115. 1150 forj=1tod(i)*2:f=f(i)+peek(s+27)/2
  116. 1160 pokes+0,fand255:pokes+1,int(f/256)
  117. 1170 next:pokes+4,16:next
  118. 1180 return
  119. 1190 rem --- new high score ---
  120. 1200 fori=1to3:forj=1to3
  121. 1210 pokes+5,62:pokes+6,48
  122. 1220 pokes+1,j*3+6:pokes,54
  123. 1230 pokes+4,33:forde=1to108:next
  124. 1240 pokes+4,32::forde=1to10:next
  125. 1250 next:next:return
  126. 1260 rem --- bonus 1000 ---
  127. 1270 pokes+6,240:pokes+4,17
  128. 1280 fori=1to14:forde=1to185step10
  129. 1290 pokes+1,de:next:poke53280,20-i:next
  130. 1300 pokes+4,0:return
  131. 1310 rem --- cursor ---
  132. 1320 f=(fand7)+1:printmid$(cr$,f,1)"[157]";
  133. 1330 forde=1to30:next:return
  134. 1340 rem --- check drive ---
  135. 1350 open15,dv,15,"r0:"+f$+"="+f$:input#15,er:close15
  136. 1360 return
  137. 1370 rem --- main ---
  138. 1380 ifbn=2thengosub560
  139. 1390 gosub270:gosub320:gosub90:gosub370
  140. 1400 gosub470:r%=1:c%=1:gosub900
  141. 1410 geta$:ifa$<>""then1410
  142. 1420 j=peek(jy)and15:geta$
  143. 1425 ifa$="q"thenqt=qt+21-qn:goto2330
  144. 1430 if(peek(jy)and16)=.ora$=chr$(13)then1510
  145. 1440 ifj=14ora$="[145]"thengosub880:r%=r%-1-(r%=1)*8:goto1490
  146. 1450 ifj=13ora$=""thengosub880:r%=r%+1+(r%=8)*8:goto1490
  147. 1460 ifj=11ora$="[157]"thengosub880:c%=c%-1-(c%=1)*2:goto1490
  148. 1470 ifj=7ora$=""thengosub880:c%=c%+1+(c%=2)*2:goto1490
  149. 1480 goto1420
  150. 1490 gosub900:gosub980:goto1420
  151. 1500 rem --- check answer ---
  152. 1510 ifch$(a)<>an$(qt)thenpv=50:bn=0:gosub1020:gosub880:gosub740:goto1530
  153. 1520 gosub1080:sc=sc+pv:gosub510:pv=pv+50:bn=bn+1:ifbn=3thenbn=0:goto1570
  154. 1530 forde=1to2500:next:gosub690
  155. 1540 qt=qt+1:qn=qn+1:ifqn>20then2110
  156. 1550 goto1380
  157. 1560 rem --- bonus rock ---
  158. 1570 forde=1to2000:next:gosub860
  159. 1580 poke53265,peek(53265)or64
  160. 1590 poke53280,6:poke53281,10:poke53282,3:poke53283,8:poke53284,7
  161. 1600 pokes+24,15:pokes+1,30:pokes+6,200
  162. 1610 c%=1:r%=rnd(1)*20+1
  163. 1620 print"[147][144][160][160][160][160][160][160][160][160][160][160][160][160][160][160][160][194][207][206][213][211][160][210][207][204][204][160][160][160][160][160][160][160][160][160][160][160][160][160][160][157][148][160]"
  164. 1630 print"[156][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][157][148][165]"
  165. 1640 print"[165][165]                             [144]&  100 [146][156][165][157][148][165]"
  166. 1650 print"[165][165]                             [144]&  150 [156][165][157][148][165]"
  167. 1660 print"[165][165]                             [144]&  200 [146][156][165][157][148][165]"
  168. 1670 print"[165][165]                             [144]&  250 [156][165][157][148][165]"
  169. 1680 print"[165][165]                             [144]&  300 [146][156][165][157][148][165]"
  170. 1690 print"[165][165]                             [144]&  350 [156][165][157][148][165]"
  171. 1700 print"[165][165]                             [144]&  400 [146][156][165][157][148][165]"
  172. 1710 print"[165][165]                             [144]&  450 [156][165][157][148][165]"
  173. 1720 print"[165][165]                             [144]&  500 [146][156][165][157][148][165]"
  174. 1730 print"[165][165]                             [144]&  750 [156][165][157][148][165]"
  175. 1740 print"[165][165]                             [144]& 1000 [146][156][165][157][148][165]"
  176. 1750 print"[165][165]                             [144]&  750 [156][165][157][148][165]"
  177. 1760 print"[165][165]                             [144]&  500 [146][156][165][157][148][165]"
  178. 1770 print"[165][165]                             [144]&  450 [156][165][157][148][165]"
  179. 1780 print"[165][165]                             [144]&  400 [146][156][165][157][148][165]"
  180. 1790 print"[165][165]                             [144]&  350 [156][165][157][148][165]"
  181. 1800 print"[165][165]                             [144]&  300 [146][156][165][157][148][165]"
  182. 1810 print"[165][165]                             [144]&  250 [156][165][157][148][165]"
  183. 1820 print"[165][165]                             [144]&  200 [146][156][165][157][148][165]"
  184. 1830 print"[165][165]                             [144]&  150 [156][165][157][148][165]"
  185. 1840 print"[165][165]                             [144]&  100 [146][156][165][157][148][165]"
  186. 1850 print"[165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][165][157][148][165]"
  187. 1860 print"[144][160][160][160][160][160][160][160][160][160][208][210][197][211][211][160][211][208][193][195][197][194][193][210][160][212][207][160][210][207][195][203][160][160][160][160][160][160][160][160][157][148][160]"
  188. 1870 r%=r%+c%:ifr%<2orr%>20thenc%=-c%:pokes+4,17:poke53280,1
  189. 1880 forde=1to20:next:poke53280,6:pokes+4,16
  190. 1890 geta$:ifa$<>" "then1870
  191. 1900 sp$=" ":bl$="&":ifr%and1thensp$=" ":bl$="&"
  192. 1910 poke214,r%:print""
  193. 1920 fori=2to31:printtab(i)bl$;
  194. 1930 pokes+1,i*2:pokes+4,17:forde=1to40:next:ifi<>31thenprint"[157]"sp$"[145]"
  195. 1940 next:pokes+4,16:print
  196. 1950 ifr%=11thengosub1270
  197. 1960 forde=1to2500:next:gosub860
  198. 1970 poke53281,.:poke53280,.
  199. 1980 poke53265,peek(53265)and191
  200. 1990 gosub180:gosub270:gosub320:gosub510
  201. 2000 poke214,10:print:r%=r%-1
  202. 2010 fori=1to3:printtab(13)"[129]             ";:ifr%=10thenprint" ";
  203. 2020 print:next:poke214,11:print
  204. 2030 printtab(14)"bonus ="bn(r%)
  205. 2040 forde=1to500:next
  206. 2050 fori=10tobn(r%)step10
  207. 2060 pokes+1,i/10:pokes+4,33:sc=sc+10
  208. 2070 gosub510:pokes+4,0:next
  209. 2080 gosub1080:forde=1to1000:next
  210. 2090 gosub650:goto1540
  211. 2100 rem --- game over ---
  212. 2110 ifsc<=hsthen2330
  213. 2120 rem --- a new champ ---
  214. 2130 gosub860:gosub1200
  215. 2140 poke214,6:print
  216. 2150 printtab(12)"[150]congratulations!"
  217. 2160 printtab(9)"[158]you are the new champ!"
  218. 2170 printtab(10)"[156][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
  219. 2180 printtab(10)"[192]                 [192]"
  220. 2190 printtab(10)"[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
  221. 2200 printtab(12)"[153]enter your name"
  222. 2210 printtab(11)"[129]then press return"
  223. 2220 rem --- input name ---
  224. 2230 hs=sc:n$="":poke214,11:print
  225. 2240 printtab(12)"[166][157]";
  226. 2250 geta$:ifa$<>""then2250
  227. 2260 geta$:ifa$=""thengosub1320:goto2260
  228. 2270 ifa$=chr$(20)andlen(n$)thenn$=left$(n$,len(n$)-1):print" [157][157]";:goto2310
  229. 2280 ifa$=chr$(13)andlen(n$)thenprint" ":goto2320
  230. 2290 ifa$<>" "anda$<"a"ora$>"z"orlen(n$)>14then2260
  231. 2300 n$=n$+a$:printa$;
  232. 2310 gosub1320:goto2260
  233. 2320 rem --- meet the mistress ---
  234. 2330 poke53265,peek(53265)and239
  235. 2340 print"[147][154][213][215]   [213]  [214][215]   [213][214]  [216]    [215][213][215] [214][215]  [215]   [215][214][213] [216][157][148] "
  236. 2350 print" in all the known galaxies there is one"
  237. 2360 print" whose knowledge of the stars surpasses"
  238. 2370 print"  all others. and for this reason only"
  239. 2380 print"[154][213]   she is truly worthy of the title [154][214][157][148][215]"
  240. 2390 print"     [159]star-mistress...extraordinaire! [154][213]"
  241. 2400 print"[216]  [213][214]    [216] [216] [214]             [214]     [213] [215][216]"
  242. 2410 print" [158][190][154]  [216] [215]   [213]     [213] [150][160][161][162][163][154] [214]  [213]  [213] [153][188]      [154][214][157][148] "
  243. 2420 print"       [214]  [214]  [129][183][184]   [150][164][165][166][167][168][154] [213]         [214][213]  [216]"
  244. 2430 print"  [213]   [213] [215]    [129][185][186] [154][215] [150][169][170][171][172][173]     [154][216]   [213][214]   [215]"
  245. 2440 print"[214]      [216]   [215] [213] [216] [150][193][194][195][196][197][146][154]       [213]     [216][189][154] [213][157][148] "
  246. 2450 print"    [191][154] [216]   [214][216]     [150][198][199][200][201][202][203][146][154] [213]         [215] [214]"
  247. 2460 print"[213]   [213]  [214]   [214]  [214] [150][204][205][206][207][208][209][210][146][154]          [214] [214]  [214]"
  248. 2470 print"     [216]    [215]     [150][211][212][213][214][215][216][146][154]    [213]       [216] [213][216]"
  249. 2480 print" [214]   [215]  [213]   [214] [215][216][150][217][218][219][220][221][146][154]  [214] [216]          [213][157][148] "
  250. 2490 print"[215]     [213]         [150][255][223][160][161][162][163][146][154] [213] [215]          [214]"
  251. 2500 print" [215][216] [214]  [214] [215] [214]      [150][164][165][166][167][168][146][154]      [213]       [216][215][157][148] "
  252. 2510 print"       [174][175][176][154]     [213]  [150][169][170][171][172][146][154]   [215] [216]      [214]  [154][213]"
  253. 2520 print" [214]   [214] [177][178][179][154] [215] [214]   [150][173][174][175][176][177][146][154]  [213][214]  [156][187][154] [214]     [216]"
  254. 2530 print"  [214]    [180][181][182][154]   [215]  [215] [150][178][179][146][154][215][150][180][181][146][154]       [213]      [213][216][157][148][215]"
  255. 2540 print"[213] [215][216]   [213]    [213] [216]  [150][182][183][184][185][186][187][146][154]  [216] [215]     [213]  "
  256. 2550 print"       [214] [216][214]    [215]  [150][188][189][146][154][213][150][190][191][146][154]     [213][214]  [215]     "
  257. 2560 print"   [214]     [215]    [214]  [216]     [216]   [216] [216]   [216]    [214][157][148] "
  258. 2570 print" [216][215]  [216] [215] [159]save score? (y[159]) or (n[159])[154] [214] [215][213]  [214]"
  259. 2580 print"[214] [216]   [214][216][213] [215]  [214][216] [215]  [213][216]   [214][213][215]     [216][214][215]  [213][214][157][148] "
  260. 2590 poke214,13-len(n$)/2:print:printtab(30-len(n$)/2)"[158]";
  261. 2600 iflen(n$)and1thenprint"";
  262. 2610 fori=1tolen(n$):printmid$(n$,i,1)"";:next
  263. 2620 a$=str$(hs):a$=right$(a$,len(a$)-1)
  264. 2630 poke214,12-len(a$)/2:print:printtab(32-len(a$)/2)"";
  265. 2640 iflen(a$)and1thenprint"";
  266. 2650 fori=1tolen(a$):printmid$(a$,i,1)"";:next
  267. 2660 gosub1130:poke53265,peek(53265)or16
  268. 2670 geta$:ifa$="n"then2770
  269. 2680 ifa$<>"y"then2670
  270. 2690 rem --- save scores ---
  271. 2700 poke214,22:print
  272. 2710 printtab(9)"[159]   [192][146] saving score [192][146]   "
  273. 2720 open15,dv,15,"s0:mistress.high":close15
  274. 2730 open8,dv,8,"mistress.high,p,w"
  275. 2740 print#8,n$:print#8,hs
  276. 2750 close8
  277. 2760 rem --- another game ---
  278. 2770 poke214,22:print
  279. 2780 printtab(9)"[159]play again? (y[159]) or (n[159])"
  280. 2790 geta$:ifa$<>""then2790
  281. 2800 geta$:ifa$="n"then2870
  282. 2810 ifa$<>"y"then2800
  283. 2820 rem --- reset variables ---
  284. 2830 sc=0:bn=0:pv=50:qn=1
  285. 2840 ifqt>n%thenqt=1:gosub3660
  286. 2850 gosub180:goto1380
  287. 2860 rem --- asta lavista baby ---
  288. 2870 f$="hello connect":gosub1350
  289. 2880 poke56578,peek(56578)or3
  290. 2890 poke56576,(peek(56576)and252)or3
  291. 2900 poke53272,21:poke648,4
  292. 2910 ifer=63then2950
  293. 2920 poke53281,6:poke53280,14:print"[147][154]"
  294. 2930 end
  295. 2940 rem --- return to loadstar ---
  296. 2950 a$="hello connect":q$=chr$(34)
  297. 2960 print"[147][144]load"q$a$q$","dv
  298. 2970 print:print:print:print:print"run"
  299. 2980 poke631,19:poke632,13:poke633,13:poke198,3:end
  300. 2990 rem --- set up video ---
  301. 3000 poke56578,peek(56578)or3:poke56576,(peek(56576)and252)
  302. 3010 poke53272,29:poke648,196
  303. 3020 poke53281,0:poke53280,0:print"[147]"
  304. 3030 return
  305. 3040 rem --- initialize ---
  306. 3050 dima,f,i,j,t,r%,c%,rn,an,pv,sc,hs,bn,de,er,fl,a$,f$,n$,bl$,sp$
  307. 3060 n%=200:jy=56320:s=54272:pv=50:qn=1:qt=1:rn=rnd(-ti)
  308. 3070 c$="[159][153][158][129][150]":cr$=" [\]^]\["
  309. 3080 b0$="                  ":b1$="                  "
  310. 3090 f$="mistress.high":gosub1350
  311. 3100 ifer<>63then3130
  312. 3110 open8,dv,8,"mistress.high"
  313. 3120 input#8,n$:input#8,hs:close8
  314. 3130 dimqt$(n%),an$(n%),ch$(16),f(16),d(16),bn(20),t$(24)
  315. 3140 fori=1ton%:readqt$(i):next
  316. 3150 fori=1ton%:readan$(i):next
  317. 3160 fori=.to16:readf(i),d(i):next
  318. 3170 fori=.to20:readbn(i):next
  319. 3180 fori=.to24:readt$(i):next
  320. 3190 gosub3660:gosub960
  321. 3200 rem --- title screen ---
  322. 3210 print"[147]":poke214,11:print
  323. 3220 print"[129]^[149]^                                 ^[129]=#>[157][148]#"
  324. 3230 fori=1to12
  325. 3240 poke214,12+i:sys58732:printt$(12+i)
  326. 3250 poke214,12-i:sys58732:printt$(12-i)
  327. 3260 next:forde=1to1000:next
  328. 3270 poke214,12:print""
  329. 3280 printtab(10)"loadstar presents"
  330. 3290 forde=1to2500:next:gosub820
  331. 3300 poke214,10:print
  332. 3310 printtab(18)"a"
  333. 3320 printtab(10)"movie star trivia"
  334. 3330 printtab(13)"game sequel"
  335. 3340 forde=1to3000:next:gosub820
  336. 3350 poke214,12:print
  337. 3360 printtab(11)"by anthony rose[154]"
  338. 3370 forde=1to2500:next:gosub820
  339. 3380 a$="[213][214][214][215][215][216]"
  340. 3390 fori=1to170
  341. 3400 poke214,rnd(1)*17+4:print
  342. 3410 printtab(rnd(1)*33+2)mid$(a$,rnd(1)*6+1,1)
  343. 3420 next
  344. 3430 poke214,5:print"[158]"
  345. 3440 print"[195][196][199][206][200][195][196][206][196][195][206][196][206][195][196][199][206][200][206][196][199][200][195][196][195][196][199][200][195][196]"
  346. 3450 print"[193][207][193][193][193][193][193][193][193][193][193][193][207][193][193][193][193][193][207][193][207][193][193][207]"
  347. 3460 print"[197][196][193][203][204][203][209][193][193][193][193][197][196][193][203][209][203][210][197][196][197][196][203][210][197][196]"
  348. 3470 print"[208][193][193][193][193][193][193][193][193][193][193][208][193][193][193][193][193][208][193][208][193][193][208][193]"
  349. 3480 print"[197][198][207][207][207][207][207][207][207][207][205][197][198][207][207][207][201][202][197][198][197][198][201][202][197][198]"
  350. 3490 forde=1to1500:next:print
  351. 3500 printtab(14)"[199][210][199][196][195][196][195][206][196]"
  352. 3510 printtab(14)"[203][210][203][209][193][193][193][193][193]"
  353. 3520 printtab(14)"[207][207][207][197][198][207][207][207]"
  354. 3530 forde=1to1500:next:print
  355. 3540 print"[208][208][195][194][196][208][208][218][255][223][219][208][208][195][194][196][195][194][196][199][194][196]"
  356. 3550 print"[193][193][193][193][193][193][220][217][221][193][193][193][193][193][193][193][193]"
  357. 3560 print"[203][194][204][193][193][193][193][193][193][223][255][193][193][193][193][193][193][193]"
  358. 3570 print"[193][193][193][193][193][193][193][193][223][221][220][255][193][193][193][193][193][193][193]"
  359. 3580 print"[207][207][197][194][198][201][194][210][201][194][210][207][201][221][220][202][197][194][198][197][194][198][201][194][198]"
  360. 3590 forde=1to1500:next
  361. 3600 printtab(6)"[149]need directions? (y) or (n)"
  362. 3610 geta$:ifa$="n"thengosub860:goto3640
  363. 3620 ifa$<>"y"then3610
  364. 3630 gosub860:gosub7060
  365. 3640 gosub180:goto1380
  366. 3650 rem --- mix questions ---
  367. 3660 print"[147]":poke214,11:print
  368. 3670 printtab(16)"[150]working..."
  369. 3680 fori=1ton%:rn=rnd(1)*n%+1
  370. 3690 a$=qt$(i):f$=an$(i):qt$(i)=qt$(rn):an$(i)=an$(rn):qt$(rn)=a$:an$(rn)=f$
  371. 3700 next:return
  372. 3710 rem --- questions ---
  373. 3720 datawho played photographer vicki vale+in $batman$
  374. 3730 datawho portrayed catwoman in the 1966+movie $batman$
  375. 3740 datawho played a female medical student+in $flatliners$
  376. 3750 datawho was a woman caught in a maze in+$hellbound@ hellraiser ii$
  377. 3760 datawho plays the man of steel's mother+in $superman$
  378. 3770 datawho was a princess in the arthurian+sci-fi movie $krull$
  379. 3780 datawho played a damsel in distress in+$quest for the mighty sword$
  380. 3790 datawho played the little girl newt in+$aliens$
  381. 3800 datawacky space rays make her quite big+in $attack of the 50-foot woman$
  382. 3810 datawho played melina in the futuristic+thriller $total recall$
  383. 3820 datawho plays the title role in stephen+king's $carrie$
  384. 3830 datashe plays the high school football+coach in $wildcats$
  385. 3840 datawhich actress pursues a sorcerer in+$warlock$
  386. 3850 datawho starred as a ny police officer+in $blue steel$
  387. 3860 datawhich actress was lady fairchild in+$mysterious island$
  388. 3870 datawho plays kay in the horror classic+$creature from the black lagoon$
  389. 3880 datawho was lori in the sci-fi thriller+$total recall$
  390. 3890 datawho stars as the comic-book heroine+in $red sonja$
  391. 3900 datawho portrayed reporter lois lane in+$superman$
  392. 3910 datawho portrayed the jungle heroine in+$sheena$
  393. 3920 datawho portrayed princess buttercup in+$the princess bride$
  394. 3930 datawho played the scientist's daughter+in $forbidden planet$
  395. 3940 datawhich star portrays a schizophrenic+in $the locket$
  396. 3950 datashe marries a salesman suspected of+murder in $betrayed$
  397. 3960 datawho played lust in the british film+$bedazzled$
  398. 3970 datawho plays an exotic smuggling queen+in $octopussy$
  399. 3980 datawho had the title role in the 1963+epic $cleopatra$
  400. 3990 datawho stars as a free-spirited mother+in $mermaids$
  401. 4000 datawho was margaret in the zany comedy+$bedazzled$
  402. 4010 datawho was arnold's female sidekick in+$conan$
  403. 4020 datawho played a navy flight instructor+in $top gun$
  404. 4030 datawhich actress won the oscar for her+role in $misery$
  405. 4040 datawho plays explorer richard burton's+wife in $mountains on the moon$
  406. 4050 datashe's battling futuristic bad guys+in $cherry 2000$
  407. 4060 datawho is a woman seeking supernatural+help in $grave secrets$
  408. 4070 datawho played a resurrected house-wife+in $hello again$
  409. 4080 datawho played a sorceress in the movie+$the witches$
  410. 4090 datawhich actress played a roller derby+star in $kansas city bomber$
  411. 4100 datawhich actress portrayed a medium in+$black rainbow$
  412. 4110 datawho starred opposite tom hanks in+$joe versus the volcano$
  413. 4120 datawho was a woman mixed up with rival+aliens in $peacemaker$
  414. 4130 datawho plays a heiress with amnesia in+$overboard$
  415. 4140 datawhich actress played a psychiatrist+in $mr. frost$
  416. 4150 datawhat star won an oscar for her role+in $gaslight$
  417. 4160 datawho starred as a futuristic teen in+$the girl from tomorrow$
  418. 4170 datawhich actress plays a time-traveler+in $millennium$
  419. 4180 datawho plays a ghost haunting a writer+in $the forgotten one$
  420. 4190 datawho played helen in hammer studios'+$dracula-prince of darkness$
  421. 4200 datawho played maria in hammer studios'+$dracula has risen from the grave$
  422. 4210 datawho played a replicant named rachel+in $bladerunner$
  423. 4220 datawho was swampy's romantic interest+in $the return of swamp thing$
  424. 4230 datawho plays jane in the award winning+(not!) $tarzan the apeman$
  425. 4240 datawho plays a mother trapped with her+son in $cujo$
  426. 4250 datawho was a woman with feline lineage+in $cat people$
  427. 4260 datawhich star won a best actress oscar+in $suspicion$
  428. 4270 datawho plays a widow who hires a handy+man in $beware my lovely$
  429. 4280 datawhich actress had the title role in+$the legend of billie jean$
  430. 4290 datawho plays a woman battling a killer+robot in $hardware$
  431. 4300 datawhich actress makes a deal with the+devil in $limit up$
  432. 4310 datawho won best supporting actress for+$ghost$
  433. 4320 datawho was a model in the supernatural+shocker $sentinel$
  434. 4330 datawhat star played a domineering wife+in $shrike$
  435. 4340 datawho played tina in the supernatural+thriller $voodoo dawn$
  436. 4350 datawhich actress had the title role in+$the story of snow white$
  437. 4360 datawhich starlet had the title role in+disney's $sleeping beauty$
  438. 4370 datawhich starlet played the title role+in $roxanne$
  439. 4380 datawho played lori in the clive barker+movie $nightbreed$
  440. 4390 datawho portrays mel gibson's mother in+$hamlet$
  441. 4400 datawho plays a psychic criminal hunter+in $fear$
  442. 4410 datawho portrayed a female scientist in+$fantastic voyage$
  443. 4420 datawho co-starred with william hurt in+$altered states$
  444. 4430 datawho co-stars with best friend james+woods in $the boost$
  445. 4440 datawho played elsa in the horror flick+$frankenstein meets the wolfman$
  446. 4450 datawho starred in the british chiller+$five million years to earth$
  447. 4460 datawho played a stone-age cavewoman in+$one million years b.c$
  448. 4470 datawho played mina in the 1931 classic+$dracula$
  449. 4480 datawhich actress starred in the comedy+$adventures in babysitting$
  450. 4490 datawho plays a teacher seeking revenge+in $hell high$
  451. 4500 datawho stars as an apprentice witch in+$bedknobs and broomsticks$
  452. 4510 datawho co-starred with martin sheen in+$the believers$
  453. 4520 datawho portrayed bruce willis' wife in+$diehard$
  454. 4530 datawho starred opposite patrick swayze+in $dirty dancing$
  455. 4540 datawho plays the female biker-she wolf+in $easy wheels$
  456. 4550 datawhich actress played the title role+in $barbarella$
  457. 4560 datawho starred opposite yul brynner in+$the king and i$
  458. 4570 datawho was john voight's reincarnated+lover in $eternity$
  459. 4580 datawho co-starred with bruce willis in+$in country$
  460. 4590 datawho plays a woman who fakes her own+murder in $kill me again$
  461. 4600 datawho plays maggie in the horror film+$popcorn$
  462. 4610 datawho plays a little girl who helps a+reindeer in $prancer$
  463. 4620 datawho starred in the 1991 blockbuster+$silence of the lambs$
  464. 4630 datawhich actress had the title role in+$private benjamin$
  465. 4640 datawhich star was marisa in the horror+spoof $transylvania twist$
  466. 4650 datawhich actress portrayed an alien in+$aftershock$
  467. 4660 datawho played a mother seeking revenge+in $obsessed$
  468. 4670 datawho plays a woman who meets a robot+in $short circuit$
  469. 4680 datawho plays a computerized dream girl+in $weird science$
  470. 4690 datawhich star plays nora in the sci-fi+adventure $eliminators$
  471. 4700 datawho starred as the heroic ripley in+$alien$
  472. 4710 datawho co-starred with jeff bridges in+$starman$
  473. 4720 datawho co-starred with peter weller in+$robocop$
  474. 4730 datawho played a mermaid in the disney+film $splash$
  475. 4740 datashe and her boyfriend help 3 aliens+in $wavelength$
  476. 4750 datawho plays a princess in the fantasy+classic $the thief of bagdad$
  477. 4760 datawhich actress played scarlet in the+classic $gone with the wind$
  478. 4770 datawho co-starred with humphrey bogart+in $key largo$
  479. 4780 datawho starred as an expectant mother+in $the seventh sign$
  480. 4790 datawho co-starred with robert urich in+$endangered species$
  481. 4800 datawhich star won a best actress oscar+in $norma rae$
  482. 4810 datawho starred as a disturbed woman in+$straight jacket$
  483. 4820 datawhich actress is haunted by visions+in $distortions$
  484. 4830 datawho played glinda the good witch in+$the wizard of oz$
  485. 4840 datawho portrayed the lady marianne in+$rogues of sherwood forest$
  486. 4850 datawho played a mysterious hitchhiker+in $alligator eyes$
  487. 4860 datawhich star marries then murders men+in $black widow$
  488. 4870 datawho plays a woman plotting a murder+in $the lady from shanghai$
  489. 4880 datawho portrays writer mary shelley in+$frankenstein unbound$
  490. 4890 datawho teams up with michael keaton in+$the squeeze$
  491. 4900 datawho plays a flutist with nightmares+in $dream lover$
  492. 4910 datawho played jackie in the futuristic+thriller $runaway$
  493. 4920 datawhich star is stabbed in the shower+in $psycho$
  494. 4930 datawhich star won a best actress oscar+in $annie hall$
  495. 4940 datawhich star played lady catherine in+$the bandit of sherwood forest$
  496. 4950 datawhich actress starred in the disney+favorite $mary poppins$
  497. 4960 datawhich actress plays queen elizabeth+in $the sea hawk$
  498. 4970 datawho played a mother whose son wants+a bb-gun in $a christmas story$
  499. 4980 datawho starred opposite errol flynn in+$against all flags$
  500. 4990 datawho co-starred with jeff bridges in+$against all odds$
  501. 5000 datawho played a woman with telekinetic+powers in $the fury$
  502. 5010 datawho played a child with telekinetic+powers in $firestarter$
  503. 5020 datawhich actress plays sarah connor in+$terminator$
  504. 5030 datawho starred in the ghostly thriller+$the legacy$
  505. 5040 datawho played a gun-slinging mother of+two in $big bad mama$
  506. 5050 datawhich actress was a princess in the+fantasy $clash of the titans$
  507. 5060 datawhich star plays morticia in 1991's+$the addams family$
  508. 5070 datawho played erica in the wwiii drama+$red dawn$
  509. 5080 datawhich actress played queen margaret+in $the adventures of don juan$
  510. 5090 datawho was helen downing in the comedy+$who's harry crumb?$
  511. 5100 datawho played terra in the kiddie sci-+fi adventure $solarbabies$
  512. 5110 datawhich actress had the title role in+$wonder woman$
  513. 5120 datawho co-starred with bruce willis in+$blind date$
  514. 5130 datawho starred opposite william powell+in $the thin man$
  515. 5140 datawhich actress portrays a vampire in+$red blooded american girl$
  516. 5150 datawhich actress portrays cleopatra in+$serpent of the nile$
  517. 5160 datawhich actress played a scientist in+$shadowzone$
  518. 5170 datawho portrayed jane in the tv. movie+$tarzan in manhattan$
  519. 5180 datawho was the voice of mikey's sister+in $look who's talking too$
  520. 5190 datawho plays kate in the horror/comedy+$gremlins$
  521. 5200 datawho portrayed ferris' girlfriend in+$ferris bueller's day off$
  522. 5210 datawho portrayed a sightless telephone+operator in $blind fear$
  523. 5220 datawho stars in the giant grasshoppers+flick $beginning of the end$
  524. 5230 datawho was nady in the postapocalyptic+adventure $cyborg$
  525. 5240 datawho was a woman stalked by a maniac+in $dean r. koontz's whispers$
  526. 5250 datawho starred opposite robert redford+in $out of africa$
  527. 5260 datawho plays sara in the sci-fi comedy+$martians go home$
  528. 5270 datawhich actress was a tv. horror host+in $midnight$
  529. 5280 datawhich star won a best actress oscar+in $driving miss daisy$
  530. 5290 datawho played tony danza's daughter in+$she's out of control$
  531. 5300 datawho portrays catherine the great in+$the scarlet empress$
  532. 5310 datawhich star won a best actress oscar+in $mrs. miniver$
  533. 5320 datawho portrayed ray milland's wife in+$dial m for murder$
  534. 5330 datawho co-starred with nicolas cage in+$wild at heart$
  535. 5340 datawho plays a girl trapped in a house+in $you'll like my mother$
  536. 5350 datawho co-starred with humphrey bogart+in $the two mrs. carrolls$
  537. 5360 datawho played the head of a school for+young women in $the beguiled$
  538. 5370 datawho co-starred with marc singer in+$the beastmaster$
  539. 5380 datawho portrays a runaway housewife in+$the rain people$
  540. 5390 datawho plays mrs. brody in the classic+thriller $jaws$
  541. 5400 datawho portrays josette in the wartime+thriller $journey into fear$
  542. 5410 datawho co-starred with stewart granger+in $king solomon's mines$
  543. 5420 datawhich actress played jean in 1935's+$the raven$
  544. 5430 datawhich star played a killer android+in $eve of destruction$
  545. 5440 datawho co-starred with leonard whiting+in $romeo and juliet$
  546. 5450 datawho played an amish widow whose son+sees a murder in $witness$
  547. 5460 datawho co-starred with roddy piper in+$hell comes to frogtown$
  548. 5470 datawho played alex forrest in the film+$fatal attraction$
  549. 5480 datawho starred in the steven spielberg+thriller $poltergeist$
  550. 5490 datawhich star plays breathless mahoney+in $dick tracy$
  551. 5500 datawho co-starred with dennis quaid in+$the big easy$
  552. 5510 datawhich actress portrayed penelope in+$the creeping flesh$
  553. 5520 datawhich actress played calamity jane+in $the paleface$
  554. 5530 datawhich actress had her last role in+$brainstorm$
  555. 5540 datawho co-starred with patrick swayze+in $roadhouse$
  556. 5550 datawho portrayed a malevolent nurse in+$one flew over the cuckoos nest$
  557. 5560 datawhich actress played billy kwan in+$the year of living dangerously$
  558. 5570 datawho starred opposite jeff goldblum+in $the fly$
  559. 5580 datawhich actress had the title role in+$peggy sue got married$
  560. 5590 datawho played pamela in the ghost film+$the uninvited$
  561. 5600 datawho co-starred with kirk douglas in+$the bad and the beautiful$
  562. 5610 datawho played robin hood's daughter in+$son of robin hood$
  563. 5620 datawho played claire in the underwater+adventure $lords of the deep$
  564. 5630 datawho played willie in the underwater+thriller $leviathan$
  565. 5640 datawhich actress starred in the slimey+thriller $frogs$
  566. 5650 datawho gives birth to a killer baby in+$the devil within her$
  567. 5660 datawhich star plays megan in the movie+$critters 2@ the main course$
  568. 5670 datawho played lora in the sci-fi movie+$alien warrior$
  569. 5680 datawhich actress was a lady vampire in+$lair of the white worm$
  570. 5690 datawhich actress portrays lt. savik in+$star trek ii@ the wrath of khan$
  571. 5700 datawhich starlet had the title role in+$phoenix the warrior$
  572. 5710 datawhich actress played chrissy in the+film $class of nuke 'em high$
  573. 5720 rem --- answers ---
  574. 5730 datakim basinger,lee meriwether
  575. 5740 datajulia roberts,ashley laurence
  576. 5750 datasusannah york,lysette anthony
  577. 5760 datamargaret lenzey,carrie henn
  578. 5770 dataallison hayes,rachel ticotin
  579. 5780 datasissey spacek,goldie hawn
  580. 5790 datalori singer,jamie lee curtis
  581. 5800 datajoan greenwood,julia adams
  582. 5810 datasharon stone,brigitte nielsen
  583. 5820 datamargot kidder,tanya roberts
  584. 5830 datarobin wright,anne francis
  585. 5840 datalaraine day,kim hunter
  586. 5850 dataraquel welch,maud adams
  587. 5860 dataelizabeth taylor,cher
  588. 5870 dataeleanor bron,sandahl bergman
  589. 5880 datakelly mcgillis,kathy bates
  590. 5890 datafiona shaw,melanie griffith
  591. 5900 datarenee soutendijk,shelley long
  592. 5910 dataanjelica huston,raquel welch
  593. 5920 datarosanna arquette,meg ryan
  594. 5930 datahilary shepard,goldie hawn
  595. 5940 datakathy baker,ingrid bergman
  596. 5950 datakatharine cullen,cheryl ladd
  597. 5960 datablair parker,barbara shelley
  598. 5970 dataveronica carlson,sean young
  599. 5980 dataheather locklear,bo derek
  600. 5990 datadee wallace,nastassia kinski
  601. 6000 datajoan fontaine,ida lupino
  602. 6010 datahelen slater,stacey travis
  603. 6020 datanancy allen,whoopi goldberg
  604. 6030 datacristina raines,june allyson
  605. 6040 datagina gershon,sarah patterson
  606. 6050 datatahnee welch,daryl hannah
  607. 6060 dataanne bobby,glenn close
  608. 6070 dataally sheedy,raquel welch
  609. 6080 datablair brown,sean young
  610. 6090 datallona massey,barbara shelley
  611. 6100 dataraquel welch,helen chandler
  612. 6110 dataelisabeth shue,maureen mooney
  613. 6120 dataangela lansbury,helen shaver
  614. 6130 databonnie bedelia,jenifer grey
  615. 6140 dataeileen davidson,jane fonda
  616. 6150 datadeborah kerr,eileen davidson
  617. 6160 dataemily lloyd,joanne w. kilmer
  618. 6170 datajill schoelen,rebecca harrell
  619. 6180 datajodie foster,goldie hawn
  620. 6190 datateri copley,elizabeth kaitan
  621. 6200 datakerrie keane,ally sheedy
  622. 6210 datakelly lebrock,denise crosby
  623. 6220 datasigourney weaver,karen allen
  624. 6230 datanancy allen,daryl hannah
  625. 6240 datacherie currie,june duprez
  626. 6250 datavivien leigh,lauren bacall
  627. 6260 datademi moore,jobeth williams
  628. 6270 datasally field,joan crawford
  629. 6280 dataolivia hussey,billie burke
  630. 6290 datadiana lynn,annabelle larsen
  631. 6300 datatheresa russell,rita hayworth
  632. 6310 databridget fonda,rae dawn chong
  633. 6320 datakristy mcnichol,kirstie alley
  634. 6330 datajanet leigh,diane keaton
  635. 6340 dataanita louise,julie andrews
  636. 6350 dataflora robson,melinda dillon
  637. 6360 datamaureen o'hara,rachel ward
  638. 6370 dataamy irving,drew barrymore
  639. 6380 datalinda hamilton,katharine ross
  640. 6390 dataangie dickenson,judi bowker
  641. 6400 dataanjelica huston,lea thompson
  642. 6410 dataviveca lindfors,annie potts
  643. 6420 datajamie gertz,cathy lee crosby
  644. 6430 datakim basinger,myrna loy
  645. 6440 dataheather thomas,rhonda fleming
  646. 6450 datalouise fletcher,kim crosby
  647. 6460 dataroseanne barr,phoebe cates
  648. 6470 datamia sara,shelley hack
  649. 6480 datapeggie castle,deborah richter
  650. 6490 datavictoria tennant,meryl streep
  651. 6500 datamargaret colin,lynn redgrave
  652. 6510 datajessica tandy,ami dolenz
  653. 6520 datamarlene dietrich,greer garson
  654. 6530 datagrace kelly,laura dern
  655. 6540 datapatty duke,barbara stanwyck
  656. 6550 datageraldine page,tanya roberts
  657. 6560 datashirley knight,lorraine gary
  658. 6570 datadolores del rio,deborah kerr
  659. 6580 datairene ware,renee soutendijk
  660. 6590 dataolivia hussey,kelly mcgillis
  661. 6600 datasandahl bergman,glenn close
  662. 6610 datajobeth williams,madonna
  663. 6620 dataellen barkin,lorna heilbron
  664. 6630 datajane russell,natalie wood
  665. 6640 datakelly lynch,louise fletcher
  666. 6650 datalinda hunt,geena davis
  667. 6660 datakathleen turner,ruth hussey
  668. 6670 datalana turner,june laverick
  669. 6680 datapriscilla barnes,amanda pays
  670. 6690 datajoan van ark,joan collins
  671. 6700 dataliane curtis,pamela saunders
  672. 6710 dataamanda donohoe,kirstie alley
  673. 6720 datapeggy sands,janelle brady
  674. 6730 rem --- music data ---
  675. 6740 data 4817,2,5103,2,5407,2,8583,4,5407,2,8583,4,5407,4,8583,12,9634,2
  676. 6750 data 10207,2,10814,2,8583,2,9634,4,10814,2,8583,2,9634,4,8583,12
  677. 6760 rem --- bonus data ---
  678. 6770 data100,150,200,250,300,350,400,450,500,750,1000,750,500,450,400,350,300
  679. 6780 data250,200,150,100
  680. 6790 rem --- title screen ---
  681. 6800 data"[129]           [211]                [212]"
  682. 6810 data"[129]            [211]              [212] "
  683. 6820 data"[129]             [211]            [212]  "
  684. 6830 data"[129]^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^[157][148]^"
  685. 6840 data"[129]^[149]*^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^+[129];#<[157][148]#"
  686. 6850 data"[129]^[149]^                                 ^[129]/;/[157][148]<"
  687. 6860 data"[129]^[149]^                                 ^[129]/=/[157][148]>"
  688. 6870 data"[129]^[149]^                                 ^[129]=#>[157][148]#"
  689. 6880 data"[129]^[149]^                                 ^[129]^^^[157][148]^"
  690. 6890 data"[129]^[149]^                                 ^[129];#<[157][148]#"
  691. 6900 data"[129]^[149]^                                 ^[129]/;/[157][148]<"
  692. 6910 data"[129]^[149]^                                 ^[129]/=/[157][148]>"
  693. 6920 data"[129]^[149]^                                 ^[129]=#>[157][148]#"
  694. 6930 data"[129]^[149]^                                 ^[129]###[157][148]#"
  695. 6940 data"[129]^[149]^                                 ^[129]###[157][148]#"
  696. 6950 data"[129]^[149]^                                 ^[129]###[157][148]#"
  697. 6960 data"[129]^[149]^                                 ^[129]###[157][148]#"
  698. 6970 data"[129]^[149]^                                 ^[129]###[157][148]#"
  699. 6980 data"[129]^[149]^                                 ^[129]###[157][148]#"
  700. 6990 data"[129]^[149]^                                 ^[129]###[157][148]#"
  701. 7000 data"[129]^[149]^                                 ^[129]###[157][148]#"
  702. 7010 data"[129]^[149]^                                 ^[129]###[157][148]#"
  703. 7020 data"[129]^[149]+^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^*[129]###[157][148]#"
  704. 7030 data"[129]^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^[192]^[157][148]_"
  705. 7040 data" [149]^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^"
  706. 7050 rem --- instructions ---
  707. 7060 poke53281,.:poke53280,6:print"[147]";
  708. 7070 a$="[154]%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%[157][148]%"
  709. 7080 fori=.to23:printa$:next:printa$""
  710. 7090 print"[158]                                    "
  711. 7100 print" * * * * mistress game plan * * * * "
  712. 7110 print"                                    "
  713. 7120 print"[150]                                    "
  714. 7130 print" in each game you will be asked 20  "
  715. 7140 print" questions about movie actresses.   "
  716. 7150 print" for each question there will be a  "
  717. 7160 print" list of 16 hollywood stars. using  "
  718. 7170 print" either a joystick in port two or   "
  719. 7180 print" the cursor keys highlight who you  "
  720. 7190 print" think the answer is then press     "
  721. 7200 print" either the firebutton or return.   "
  722. 7210 print" the point value for each question  "
  723. 7220 print" begins at 50 and will increase by  "
  724. 7230 print" 50 each time you answer correctly. "
  725. 7240 print" however, if you miss a question,   "
  726. 7250 print" the point value will return to 50. "
  727. 7260 print"                                    "
  728. 7270 print"[153]                                    "
  729. 7280 print"    press firebutton to continue    "
  730. 7290 print"                                    "
  731. 7300 ifpeek(197)=64and(peek(jy)and16)then7300
  732. 7310 :
  733. 7320 gosub860:print"[147]";
  734. 7330 fori=.to23:printa$:next:printa$""
  735. 7340 print"[158]                                    "
  736. 7350 print" * * * * * the bonus roll * * * * * "
  737. 7360 print"                                    "
  738. 7370 print"[150]                                    "
  739. 7380 print" in addition to regular scoring, if "
  740. 7390 print" you correctly answer 3 questions   "
  741. 7400 print" in a row you get a bonus roll.     "
  742. 7410 print" in this game there will be a ball  "
  743. 7420 print" moving up and down the left hand   "
  744. 7430 print" side of the screen which you will  "
  745. 7440 print" release into one of the scoring    "
  746. 7450 print" pods on the right hand side of the "
  747. 7460 print" screen. however, until released,   "
  748. 7470 print" the ball is invisible so your only "
  749. 7480 print" way of determining its location    "
  750. 7490 print" will be a beep that occurs as the  "
  751. 7500 print" ball hits the top or bottom wall.  "
  752. 7510 print"                                    "
  753. 7520 print"[153]                                    "
  754. 7530 print"    press firebutton to continue    "
  755. 7540 print"                                    "
  756. 7550 ifpeek(197)=64and(peek(jy)and16)then7550
  757. 7560 gosub860:poke53280,.:return
  758. 10000 open15,8,15,"s0:star mistresses":close15:save"star mistresses",8:end
  759.